Configuraciones de filtros y codecs
-
- Mensajes: 1047
- Registrado: Sab 10 Jun, 2006 06:51
Re: Configuraciones de filtros y codecs
Si no tienes un equipo de audio con entrada óptica el pero del WD HD Media Player es el DTS. Pero todos los otros repros que listé decodifican DTS ya de fábrica.
Ah, y dije SeeSaw, no MSharpen.
Si tienes Linux puedes utilizar Avidemux + AVSProxy + Wine + AVISynth y acceder así a las bondades de SeeSaw.
Ah, y dije SeeSaw, no MSharpen.
Si tienes Linux puedes utilizar Avidemux + AVSProxy + Wine + AVISynth y acceder así a las bondades de SeeSaw.
-
- Mensajes: 100
- Registrado: Mié 07 Jul, 2004 02:00
- Ubicación: Sevilla
Re: Configuraciones de filtros y codecs
Vuelvo por aquí a molestar otro rato .
Después de haber visto lo de SeeSaw, me he animado a probarlo. Me bajé el .avsi de Didée y me leí la documentación. Ahí vi que la forma correcta de usar SeeSaw era:
El caso es que el problema viene al querer usar SeeSaw con la cadena de limpiado de MvTools que ya he posteado por aquí antes. Me he pasado varias horas con el AvsP tratando de hacer algo pero no lo consigo, así que vengo aquí a buscar ayuda.
El script final con el que me quedé en AvsP -y que igualmente deja una imagen feísima, aunque lo que es funcionar, funciona- es:
He probado de diferentes formas: descomentando la línea del chroma=source, por ejemplo, y cambiando los valores a chroma=true cuando la línea está comentada y a false cuando no lo está, etc. De todas formas en ningún caso he conseguido que la cosa funcione bien. Un par de capturas de lo que me devuelve el script al renderizar:
Como se puede ver, la imagen sale MUY granulada, casi incluso más que en el vídeo original, y también hay artefactos varios por toda la imagen y, en general, es un desastre.
No sé si habría alguna forma de convertir la cadena de acciones de mvtools en una especie de función o algo parecido que poder guardar en .avs y poder llamar en el código a modo de a = last / b = a.limpiadomvtools() o algo similar. He estado mirando la documentación de funciones pero, sinceramente, me pierdo en las variables y va a ser peor el remedio que la enfermedad.
¿Alguna idea de dónde me puedo estar equivocando? ¿En la cadena de denoising, en los parámetros de SeeSaw, en todo en general?
Después de haber visto lo de SeeSaw, me he animado a probarlo. Me bajé el .avsi de Didée y me leí la documentación. Ahí vi que la forma correcta de usar SeeSaw era:
Código: Seleccionar todo
a= last
b=a.yourfavoritedenoiser()
SeeSaw(a,b, NRlimit=3, NRlimit2=4, Sstr=1.5, Slimit=5, Spower=5, Sdamplo=6, Szp=16)
El script final con el que me quedé en AvsP -y que igualmente deja una imagen feísima, aunque lo que es funcionar, funciona- es:
Código: Seleccionar todo
DGDecode_mpeg2source("J:\THE_SHINING\VIDEO_TS\VTS_01_1.d2v", info=3)
ColorMatrix(hints=true, threads=0)
#deinterlace
crop( 2, 0, 0, 0)
Spline36Resize(720,528) # Spline36 (Neutral)
SmoothLevels(preset="tv2pc")
#denoise
SetMemoryMax(256)
source=last
backward_vec1=source.MVAnalyse(isb = true, delta = 2, pel = 2, blksize=8, overlap=4, sharp=1, idx = 1, dct=0, chroma=true)
forward_vec1=source.MVAnalyse(isb = false, delta = 2, pel = 2, blksize=8, overlap=4, sharp=1, idx = 1, dct=0, chroma=true)
backward_vec2=source.MVAnalyse(isb = true, delta = 4, pel = 2, blksize=8, overlap=4, sharp=1, idx = 1, dct=0, chroma=true)
forward_vec2=source.MVAnalyse(isb = false, delta = 4, pel = 2, blksize=8, overlap=4, sharp=1, idx = 1, dct=0, chroma=true)
backward_vec3=source.MVAnalyse(isb = true, delta = 6, pel = 2, blksize=8, overlap=4, sharp=1, idx = 1, dct=0, chroma=true)
forward_vec3=source.MVAnalyse(isb = false, delta = 6, pel = 2, blksize=8, overlap=4, sharp=1, idx = 1, dct=0, chroma=true)
#chroma=source.MVDegrain3(backward_vec3,backward_vec2,backward_vec1,forward_vec1,forward_vec2,forward_vec3,thSAD=400,idx=1,plane=3)
#source.MVDegrain3(backward_vec3,backward_vec2,backward_vec1,forward_vec1,forward_vec2,forward_vec3,thSAD=400,idx=1, plane=0)
a = last
b = a.MVDegrain3(backward_vec3,backward_vec2,backward_vec1,forward_vec1,forward_vec2,forward_vec3,thSAD=400,idx=1, plane=0)
SeeSaw(a,b,NRlimit=3, NRlimit2=4, Sstr=1.5, Slimit=5, Spower=5, Sdamplo=6, Szp=16)
gradfun2db(1.51)
Como se puede ver, la imagen sale MUY granulada, casi incluso más que en el vídeo original, y también hay artefactos varios por toda la imagen y, en general, es un desastre.
No sé si habría alguna forma de convertir la cadena de acciones de mvtools en una especie de función o algo parecido que poder guardar en .avs y poder llamar en el código a modo de a = last / b = a.limpiadomvtools() o algo similar. He estado mirando la documentación de funciones pero, sinceramente, me pierdo en las variables y va a ser peor el remedio que la enfermedad.
¿Alguna idea de dónde me puedo estar equivocando? ¿En la cadena de denoising, en los parámetros de SeeSaw, en todo en general?
-
- Mensajes: 1047
- Registrado: Sab 10 Jun, 2006 06:51
Re: Configuraciones de filtros y codecs
SeeSaw es un filtro poco intuitivo y muy rebelde! Los resultados que estás logrando son muestra clara de por donde viene esa "rebeldía" y los grupos que ripean 10 pelis por semana como los que mencionaba Morrissey21 caen continuamente en estos problemas.
La solución se resume principalmente a tener mucha paciencia y probar de todo, verás que cada DVD en particular necesita un tratamiento único. SeeSaw es la razón que herramientas como AvsP se hayan vuelto indispensables.
Para ahorrarte dolores de cabeza te invito a probar AvsP. Podrás jugar con todos los valores de los filtros a través de sliders y ver los resultados en tiempo real. Mientras pruebes no tengas miedo a utilizar todo tipo de intensidades en el denoise que se hace en b y las configuraciones finales de SeeSaw.
Si quieres ver algún ejemplo concreto para trabajar con algún DVD en particular sube un pedacito de VOB (unos 20 MB) a mediafire o similares, nos copias el enlace en este hilo y lo podremos bajar para sugerir configuraciones de SeeSaw específicas.
La solución se resume principalmente a tener mucha paciencia y probar de todo, verás que cada DVD en particular necesita un tratamiento único. SeeSaw es la razón que herramientas como AvsP se hayan vuelto indispensables.
Para ahorrarte dolores de cabeza te invito a probar AvsP. Podrás jugar con todos los valores de los filtros a través de sliders y ver los resultados en tiempo real. Mientras pruebes no tengas miedo a utilizar todo tipo de intensidades en el denoise que se hace en b y las configuraciones finales de SeeSaw.
Si quieres ver algún ejemplo concreto para trabajar con algún DVD en particular sube un pedacito de VOB (unos 20 MB) a mediafire o similares, nos copias el enlace en este hilo y lo podremos bajar para sugerir configuraciones de SeeSaw específicas.
-
- Mensajes: 100
- Registrado: Mié 07 Jul, 2004 02:00
- Ubicación: Sevilla
Re: Configuraciones de filtros y codecs
Dicho y hecho. El AvsP lo tengo y uso hace bastante tiempo, aunque algunas de las opciones más avanzadas aún no las domino bien . A ver si entre todos conseguimos sacar un script decente, que de todas formas tengo curiosidad por saber cómo pasarle los parámetros de denoising al SeeSaw con esa cadena de mvtools, que es algo que seguramente estaré haciendo mal y que pueda estar causando problemas. En fin, el trozo de VOB que pediste :
http://www.mediafire.com/?zwz2yywjmug
Un saludo.
http://www.mediafire.com/?zwz2yywjmug
Un saludo.
-
- Mensajes: 1047
- Registrado: Sab 10 Jun, 2006 06:51
Re: Configuraciones de filtros y codecs
Yo veo la fuente bastante bien. En las escenas con mucho movimiento hay algunos artefactos de compresión, pero nada que pueda a llegar a molestar mucho. Si el ripeo fuera mio, yo la dejaría así.
Pero vamos a hacer algo con SeeSaw:
1) te recomiendo largar MVTools y pasarte a MVTools2. La sintaxis es un poco distinta, los resultados finales son los mismos y es ~20% más rápido que MVTools.
2) para no hacerte lío con la sintáxis de MVTools2 puedes accederlo a través de un script que te simplifique la vida, te recomiendo MCTemporalDenoise.
3) algo que considero un problema de SeeSaw es que también hace un sharpening sobre chroma. El resultado se escapa a la vista y compromete la compresiblidad sin ser necesario. Le pregunté a Didée (el autor de filtro) como cambiarlo en este mensaje: http://forum.doom9.org/showthread.php?p ... ost1225782
De su respuesta me hice esta versión de SeeSaw que solo hace sharpen sobre Luma:
Sin preocuparme del cropeo con tu ejemplo hice por ejemplo esto que reduce algo de grano y ruido y aplica un poco de sharpen:
La comparación Original vs. Filtrado es esta:
Pero vamos a hacer algo con SeeSaw:
1) te recomiendo largar MVTools y pasarte a MVTools2. La sintaxis es un poco distinta, los resultados finales son los mismos y es ~20% más rápido que MVTools.
2) para no hacerte lío con la sintáxis de MVTools2 puedes accederlo a través de un script que te simplifique la vida, te recomiendo MCTemporalDenoise.
3) algo que considero un problema de SeeSaw es que también hace un sharpening sobre chroma. El resultado se escapa a la vista y compromete la compresiblidad sin ser necesario. Le pregunté a Didée (el autor de filtro) como cambiarlo en este mensaje: http://forum.doom9.org/showthread.php?p ... ost1225782
De su respuesta me hice esta versión de SeeSaw que solo hace sharpen sobre Luma:
Código: Seleccionar todo
# (Full Name: "Denoiser-and-Sharpener-are-riding-the-SeeSaw" )
#
# This function provides a (simple) implementation of the "crystality sharpen" principle.
# In conjunction with a user-specified denoised clip, the aim is to enhance
# weak detail, hopefully without oversharpening or creating jaggies on strong
# detail, and produce a result that is temporally stable without detail shimmering,
# while keeping everything within reasonable bitrate requirements.
# This is done by intermixing source, denoised source and a modified sharpening process,
# in a seesaw-like manner.
#
# This version is considered alpha.
#
# Usage:
#
# a = TheNoisySource
# b = a.YourPreferredDenoising()
# SeeSaw( a, b, [parameters] )
#
# You're very much encouraged to feed your own custom denoised clip into SeeSaw.
# If the "denoised" clip parameter is omitted, a simple "spatial pressdown" filter is used.
#
#
# Fiddled together by Didée, for your pleasure.
#
# this versions keeps denoised chroma as-is
# ======= Main function =======
function SeeSaw( clip clp, clip "denoised",
\ int "NRlimit",int "NRlimit2",
\ float "Sstr", int "Slimit", float "Spower", float "SdampLo", float "SdampHi", float "Szp",
\ float "bias", int "Smode", int "sootheT", int "sootheS", float "ssx", float "ssy")
{
ssx = default( ssx, 1.0 ) # supersampling factor x / SeeSaw doesn't require supersampling urgently.
ssy = default( ssy, ssx ) # supersampling factor y / if at all, small values ~1.25 seem to be enough.
NRlimit = default( NRlimit, 2 ) # absolute limit for pixel change by denoising
NRlimit2 = default( NRlimit2, NRlimit+1) # limit for intermediate denoising
Sstr = default( Sstr, 1.5 ) # Sharpening strength (don't touch this too much)
Slimit = default( Slimit, NRlimit+2 ) # positive: absolute limit for pixel change by sharpening
# negative: pixel's sharpening difference is reduced to diff=pow(diff,1/abs(limit))
Spower = default( Spower, 4 ) # exponent for modified sharpener
Szp = default( Szp, 16+2 ) # zero point - below: overdrive sharpening - above: reduced sharpening
SdampLo = default( SdampLo, Spower+1 ) # reduces overdrive sharpening for very small changes
SdampHi = default( SdampHi, 24 ) # further reduces sharpening for big sharpening changes. Try 15~30. "0" disables.
bias = default( bias, 49 ) # bias towards detail ( >= 50 ) , or towards calm result ( < 50 )
Smode = default( Smode, ssx<1.35 ? 11 : ssx<1.51 ? 20 : 19 )
sootheT = default( sootheT, 49 ) # 0=minimum, 100=maximum soothing of sharpener's temporal instableness.
# (-100 .. -1 : will chain 2 instances of temporal soothing.)
sootheS = default( sootheS, 0 ) # 0=minimum, 100=maximum smoothing of sharpener's spatial effect.
Szp = Szp / pow(Sstr, 1.0/4.0) / pow( (ssx+ssy)/2.0, 1.0/2.0 )
SdampLo = SdampLo / pow(Sstr, 1.0/4.0) / pow( (ssx+ssy)/2.0, 1.0/2.0 )
ox=clp.width
oy=clp.height
xss = m4(ox*ssx)
yss = m4(oy*ssy)
NRL = string( NRlimit )
NRL2 = string( NRlimit2 )
NRLL = string( int(round( NRlimit2 * 100.0/bias - 1.0 )) )
SLIM = string( abs(Slimit) )
BIAS1 = string( bias )
BIAS2 = string( 100-bias )
#ZRP = string( abs(Szp) )
#PWR = string( abs(Spower) )
#DMP = string( SdampLo )
denoised = defined(denoised) ? denoised : mt_lutxy(clp,clp.removegrain(4,-1),"x "+NRL+" + y < x "+NRL+" + x "+NRL+" - y > x "+NRL+" - y ? ?",chroma="copy first")
NRdiff = mt_makediff(clp,denoised,chroma="copy second")
tame = mt_lutxy(clp,denoised,"x "+NRLL+" + y < x "+NRL2+" + x "+NRLL+" - y > x "+NRL2+" - x "+BIAS1+" * y "+BIAS2+" * + 100 / ? ?")
head = tame.sharpen2(Sstr,Spower,Szp,SdampLo,SdampHi,4)
# head = head.mt_merge(tame,tame.prewitt(multiplier=1.0).mt_expand().removegrain(20))
(ssx==1.0 && ssy==1.0) ? repair(tame.sharpen2(Sstr,Spower,Szp,SdampLo,SdampHi,Smode),head,1,-1,-1)
\ : repair(tame.lanczosresize(xss,yss).sharpen2(Sstr,Spower,Szp,SdampLo,SdampHi,Smode),head.bicubicresize(xss,yss,-.2,.6),1,-1,-1).lanczosresize(ox,oy)
SootheSS(last,tame,sootheT,sootheS)
sharpdiff= mt_makediff(tame,last)
(NRlimit==0) ? clp : \
mt_lutxy(clp,NRdiff, "y 128 "+NRL+" + > x "+NRL+" - y 128 "+NRL+" - < x "+NRL+" + x y 128 - - ? ?",chroma="copy second")
Slimit>=0 ? mt_lutxy(last,sharpdiff,"y 128 "+SLIM+" + > x "+SLIM+" - y 128 "+SLIM+" - < x "+SLIM+" + x y 128 - - ? ?",chroma="copy first")
\ : mt_lutxy(last,sharpdiff,"y 128 == x x y 128 - abs 1 "+SlIM+" / ^ y 128 - y 128 - abs / * - ?",chroma="copy first")
return( last )
}
# ======= Modified sharpening function =======
function sharpen2(clip clp, float strength, int power, float zp, float lodmp, float hidmp, int rgmode)
{
STR = string( strength )
PWR = string( 1.0/float(power) )
ZRP = string( ZP )
DMP = string( lodmp )
HDMP = (hidmp==0) ? "1" : "1 x y - abs "+string(hidmp)+" / 4 ^ +"
mt_lutxy( clp, clp.RemoveGrain(rgmode,-1,-1), \
"x y == x x x y - abs "+ZRP+" / "+PWR+" ^ "+ZRP+" * "+STR+" * x y - 2 ^ x y - 2 ^ "+DMP+" + / * x y - x y - abs / * "+HDMP+" / + ?",chroma="copy first")
return( last )
}
# ======= Soothe() function to stabilze sharpening =======
function SootheSS(clip sharp, clip orig, int "sootheT", int "sootheS")
{
sootheT = default(sootheT, 25 )
sootheS = default(sootheS, 0 )
sootheT = (sootheT > 100) ? 100 : (sootheT < -100) ? -100 : sootheT
sootheS = (sootheS > 100) ? 100 : (sootheS < 0) ? 0 : sootheS
ST = string( 100 - abs(sootheT))
SSPT = string( 100 - abs(sootheS))
mt_makediff(orig,sharp)
(sootheS==0) ? last
\ : mt_lutxy( last, last.removegrain(20,-1,-1),
\ "x 128 - y 128 - * 0 < x 128 - 100 / "+SSPT+" * 128 + x 128 - abs y 128 - abs > x "+SSPT+" * y 100 "+SSPT+" - * + 100 / x ? ?", chroma="ignore")
(sootheT==0) ? last
\ : mt_lutxy( last, last.temporalsoften(1,255,0,32,2),
\ "x 128 - y 128 - * 0 < x 128 - 100 / "+ST+" * 128 + x 128 - abs y 128 - abs > x "+ST+" * y 100 "+ST+" - * + 100 / x ? ?", chroma="ignore")
(sootheT > -1) ? last
\ : mt_lutxy( last, last.temporalsoften(1,255,0,32,2),
\ "x 128 - y 128 - * 0 < x 128 - 100 / "+ST+" * 128 + x 128 - abs y 128 - abs > x "+ST+" * y 100 "+ST+" - * + 100 / x ? ?",chroma="ignore")
mt_makediff(orig,last)
# mergechroma(sharp) # not needed in SeeSaw
return( last )
}
# ======= MOD4-and-atleast-16 helper function =======
function m4(float x) {x<16?16:int(round(x/4.0)*4)}
Código: Seleccionar todo
Import("D:\AviSynth 2.5\plugins\MCTemporalDenoise.v1.3.00.avs")
Import("D:\AviSynth 2.5\plugins\SeeSaw_keep_denchr.avs")
DGDecode_mpeg2source("I:\videos\samples\prueba.d2v", info=3)
a= last
b= MCTemporalDenoise(settings="low",chroma=true,GPU=false,sharp=false)
SeeSaw(a,b, NRlimit=3, NRlimit2=4, Sstr=1.5, Slimit=2, Spower=5, Sdamplo=6, Szp=16, bias=70, soothet=60)
-
- Mensajes: 100
- Registrado: Mié 07 Jul, 2004 02:00
- Ubicación: Sevilla
Re: Configuraciones de filtros y codecs
Muchas gracias elguaxo. Tenía instalado McTemporalDenoise, y MC_Spuds también, desde hacía algún tiempo, pero nunca me había animado a usarlos hasta ahora. Leeré con calma la documentación del script, que será mejor que la cadena ésa de filtrado. ¿El parámetro GPU=false por qué lo usas, es más lento dejándolo en true?
Me guardo también el SeeSaw sólo de luma, seguramente me vendrá bien para futuros encodeos. A ver qué tal sale el ripeo .
PD: ¿por qué has prescindido de usar SmoothLevels en tu script?
Me guardo también el SeeSaw sólo de luma, seguramente me vendrá bien para futuros encodeos. A ver qué tal sale el ripeo .
PD: ¿por qué has prescindido de usar SmoothLevels en tu script?
-
- Mensajes: 1047
- Registrado: Sab 10 Jun, 2006 06:51
Re: Configuraciones de filtros y codecs
No me pareció que SmoothLevels hiciera falta.
GPU=false: MCTemporalDenoise utiliza un pre-filtrado para mejorar la exactitud con la cual MVAnalyse traza/elige los vectores de movimiento. FFT3DFilter es parte de esta cadena de pre-filtrado. Hay una versión de FFT3DFilter que puede correr todas las operaciones sobre la tarjeta de video (GPU), dejando libre la CPU. Mi tarjeta de video es capaz de correr la versión GPU de FFT3DFilter, pero como la tarjeta es MUY VIEJITA FFT3DFilter termina corriendo mucho más lento sobre la tarjeta de video que sobre mi CPU. Por eso especifiqué GPU=False.
GPU=false: MCTemporalDenoise utiliza un pre-filtrado para mejorar la exactitud con la cual MVAnalyse traza/elige los vectores de movimiento. FFT3DFilter es parte de esta cadena de pre-filtrado. Hay una versión de FFT3DFilter que puede correr todas las operaciones sobre la tarjeta de video (GPU), dejando libre la CPU. Mi tarjeta de video es capaz de correr la versión GPU de FFT3DFilter, pero como la tarjeta es MUY VIEJITA FFT3DFilter termina corriendo mucho más lento sobre la tarjeta de video que sobre mi CPU. Por eso especifiqué GPU=False.
-
- Mensajes: 100
- Registrado: Mié 07 Jul, 2004 02:00
- Ubicación: Sevilla
Re: Configuraciones de filtros y codecs
Duda aclarada, pues. Mi tarjeta de vídeo es una Nvidia 9800 GTX, así que voy a ponerle true a ver si conseguimos ganar algún fps extraviado .
Un saludo.
Un saludo.
-
- Mensajes: 1047
- Registrado: Sab 10 Jun, 2006 06:51
Re: Configuraciones de filtros y codecs
Esto le puede interesar a los aficionados al ripeo. Es un master digital del trailer de The Island, comprimido en Lagarith (lossless). El que sea un master significa que la calidad es máxima y superior a la de un Bluray. Este master se puede distribuir libremente y está pensado justamente para tests de compresión.
Aquí el enlace:
http://shimapan.users.sourceforge.net/island/
Aquí el enlace:
http://shimapan.users.sourceforge.net/island/
-
- Mensajes: 232
- Registrado: Dom 17 Abr, 2005 02:00
Re: Configuraciones de filtros y codecs
gracias, me lo bajo. como no puedo esperar para hacer las pruebas voy preguntando ¿ como es la manera correcta de cargar este tipo de videos en avisynth?
un saludo
un saludo
-
- Mensajes: 1047
- Registrado: Sab 10 Jun, 2006 06:51
Re: Configuraciones de filtros y codecs
Este en particular está codificado con un codec lossless que se llama Lagarith. Lo puedes bajar desde esta página:
http://lags.leetcode.net/codec.html
Una vez instalado el codec puedes cargar el video desde avisynth con un pequeño script como este:
AVISource("Island_1080p24_lag_51_[B76E513A].avi")
http://lags.leetcode.net/codec.html
Una vez instalado el codec puedes cargar el video desde avisynth con un pequeño script como este:
AVISource("Island_1080p24_lag_51_[B76E513A].avi")
-
- Mensajes: 232
- Registrado: Dom 17 Abr, 2005 02:00
Re: Configuraciones de filtros y codecs
perfecto, no tenia claro si era como AVIsource o como DirectShowsource.
he añadido audio = false
Gracias otra vez
PD. mi PC no puede con ese video . vaya tela jajaja
he añadido audio = false
Gracias otra vez
PD. mi PC no puede con ese video . vaya tela jajaja
-
- Mensajes: 153
- Registrado: Dom 02 Feb, 2003 01:00
Re: Configuraciones de filtros y codecs
Hola. Tengo problemas para ripear el DVD de Haxan. La fuente es así:
Me queda así:
- Spoiler: mostrar
- Spoiler: mostrar
Me queda así:
- Spoiler: mostrar
-
- Mensajes: 1047
- Registrado: Sab 10 Jun, 2006 06:51
Re: Configuraciones de filtros y codecs
Recuerdo que le ayudé a wickerman con esta misma película: http://sbigare.us/viewtopic.php?p=120429#p120429
Si tu reproductor no tiene problemas con las matrices custom, entonces aquí lo que ayuda mucho es la Jawor's 1CD. Pero si quieres dejarlo 100% compatible y no utilizar matrices, entonces te recomiendo un combo de FFT3d y Degrainmedian. Tal vez algo así como:
DeGrainMedian(mode=4).FFT3DFilter(sigma=1.5,plane=4,bt=5)
Si tu reproductor no tiene problemas con las matrices custom, entonces aquí lo que ayuda mucho es la Jawor's 1CD. Pero si quieres dejarlo 100% compatible y no utilizar matrices, entonces te recomiendo un combo de FFT3d y Degrainmedian. Tal vez algo así como:
DeGrainMedian(mode=4).FFT3DFilter(sigma=1.5,plane=4,bt=5)
-
- Mensajes: 153
- Registrado: Dom 02 Feb, 2003 01:00
Re: Configuraciones de filtros y codecs
Muchas gracias, probaré con esos filtros y comento cuando termine.
-
- Mensajes: 153
- Registrado: Dom 02 Feb, 2003 01:00
-
- Mensajes: 1047
- Registrado: Sab 10 Jun, 2006 06:51
Re: Configuraciones de filtros y codecs
Algo me huele mal... Utilizaste la misma resolución y bitrate que en tu ripeo anterior y el DRF te dió más alto cuando con ese filtrado debiera haber estado cerca del 3.2 o menos. Analizando un poco más veo a los I-Vops (keyframes) por el 3.7, cuando tendrían que haber estado entre el 2 y 3!
Le daría una mirada a las configuraciones Xvid. Si quieres copia capturas de todas las configuraciones que tengas, así desciframos el misterio.
Le daría una mirada a las configuraciones Xvid. Si quieres copia capturas de todas las configuraciones que tengas, así desciframos el misterio.
-
- Mensajes: 153
- Registrado: Dom 02 Feb, 2003 01:00
Re: Configuraciones de filtros y codecs
Ahí van, básicamente usaba la configuración que recomendaban en divxhouse con alguna modificación según lo que leí en este hilo. Lo malo es que ya hace de eso y quizá en alguna prueba que hice haya tocado algo que no debía, pero hasta ahora los ripeos me habían ido bien.
- Spoiler: mostrar
-
- Mensajes: 232
- Registrado: Dom 17 Abr, 2005 02:00
Re: Configuraciones de filtros y codecs
Es cierto lo que dice elguaxo, con un buen filtrado el drf debería salirte mejor. Quitando este pequeño misterio el ripeo pide más tamaño, deberías darle más y dejarlo en un drf de 2.8-3.0. Porque encasillarse en los 1487MB???
-
- Mensajes: 153
- Registrado: Dom 02 Feb, 2003 01:00
Re: Configuraciones de filtros y codecs
Estoy haciendo otra prueba. Si no sale bien miraré de subir el tamaño hasta 2GB.